package File::Mountpoint;

use strict;

our $VERSION = '1.0';

use base qw( Exporter );

use Carp;
use File::stat qw( :FIELDS );
use Fcntl qw( :mode );
use File::Spec;

our @EXPORT_OK = qw( is_mountpoint );

sub is_mountpoint {

    my $path = shift;
    return unless defined $path;

    # run lstat() on the path
    my $ls = lstat($path);

    # check to see if the path exists
    unless (defined $ls) {
        croak "is_mountpoint: $path: No such file or directory";
    }

    # check to make sure that the path exists and is a directory
    unless (S_ISDIR($st_mode)) {
        croak "is_mountpoint: $path: not a directory";
    }

    # store the lstat() device and inode
    my $ls_dev = $st_dev;
    my $ls_ino = $st_ino;

    # append /.. to the path and run stat() on it
    stat(File::Spec->catdir($path, "/.."));

    # store the stat() device
    my $s_dev = $st_dev;
    my $s_ino = $st_ino;

    # compare the lstat() and stat() devs
    # based directly on code from mountpoint.c
    unless (($ls_dev != $s_dev) || ($ls_dev == $s_dev && $ls_ino == $s_ino)) {
        return;
    }

    return 1;
}

1;